Difference between revisions of "Information Systems:EODUPD"
Jump to navigation
Jump to search
(Created page with "→Generate bills to suppliers for COOP AND VEDI. This has to run first: →so that generated entries will be included in the updates.: ...") |
|||
| Line 1: | Line 1: | ||
| − | /* Generate bills to suppliers for COOP AND VEDI. This has to run first */ |
+ | /* Generate bills to suppliers for COOP AND VEDI. This has to run first */ |
/* so that generated entries will be included in the updates. */ |
/* so that generated entries will be included in the updates. */ |
||
Revision as of 17:12, 4 February 2016
/* Generate bills to suppliers for COOP AND VEDI. This has to run first */
/* so that generated entries will be included in the updates. */
CXBILL03C
CALL PGM(CXBILL06)
/* Run ASW command to put the current date minus 1 (as this job is */
/* running after midnight) into the LDA (local data area) */
CHGASWLDA TYPE(*DATDZ) RELVAL(-1) STARTPOS(001)
/* Extract yesterday's date from the LDA and convert it to numeric */
RTVDTAARA DTAARA(*LDA (1 8)) RTNVAR(&DATEC)
CHGVAR VAR(&DATE) VALUE(&DATEC)
/* Call ASW program to get yesterday's fiscal period, and convert to */
/* character. */
GETPERIOD DATE(&DATE) PERIOD(&PERIOD)
CHGVAR VAR(&PERIODC) VALUE(&PERIOD)
/* Print invoice journal. This will be file DMR352P in WRKSPLF EDOJOB. */
/* There are saved parameters for this. Just change the date and period.*/
RTVASWPAR PGM(DMC352) PAID(INVJOURNAL) USER(*ALL)
CHGASWLDA TYPE(*DATDZ) RELVAL(-1) STARTPOS(082)
CHGASWLDA VALUE(&PERIODC) TYPE(*CHAR) STARTPOS(090) +
POSITIONS(6)
EXCASWPGM PGM(DMC352) PARM(N)
/* Run nightly DIS to FIN. Again, there are saved parameters for this. */
/* Change the date and period. */
RTVASWPAR PGM(GCFC751) PAID(DIS2FIN) USER(*ALL)
CHGASWLDA TYPE(*DATDZ) RELVAL(-1) STARTPOS(082)
CHGASWLDA VALUE(&PERIODC) TYPE(*CHAR) STARTPOS(090) +
POSITIONS(6)
EXCASWPGM PGM(GCFC751) PARM(N)
/* Clear intermediate purchase suggestions from yesterday. */
RTVASWPAR PGM(DIC801) PAID(CLRSUGPO) USER(*ALL)
CHGASWLDA TYPE(*DATDZ) STARTPOS(1)
EXCASWPGM PGM(DIC801) PARM(N)
/* Generate purchase suggestions. */
RTVASWPAR PGM(INVC431) PAID(PURSUG2MAI) USER(*ALL)
EXCASWPGM PGM(INVC431) PARM(N)
RTVASWPAR PGM(INVC431) PAID(PURSUG3MAI) USER(*ALL)
EXCASWPGM PGM(INVC431) PARM(N)
/* Keep copy of purchase suggestions as there are sometimes questions */
/* about whether something was generated here, or manually. */
CPYF FROMFILE(UP1480BFVA/SROPUH) +
TOFILE(UP1480BFVA/SROPUH.B1) MBROPT(*REPLACE)
CPYF FROMFILE(UP1480BFVA/SROPUL) +
TOFILE(UP1480BFVA/SROPUL.B1) MBROPT(*REPLACE)
/* Update ASW Item Cost With Effective VEBA From CCP */
CALL PGM(IXRUP880)
/* Note that we can operate if the following jobs are not run. There may */
/* be some 'unexpected results', but that will not stop us from receiving,*/
/* picking, and shipping orders. */
/* Rebuild the Time Axis File */
RTVASWPAR PGM(DMC951) PAID(TIMEAXIS) USER(*ALL)
CHGASWLDA VALUE(&PERIODC) TYPE(*CHAR) STARTPOS(007) +
POSITIONS(6)
EXCASWPGM PGM(DMC951) PARM(N)
/* Rebuild A/R Credit Time Axis */
RTVASWPAR PGM(GDMC195) PAID(ARAXIS) USER(*ALL)
EXCASWPGM PGM(GDMC195) PARM(N)
/* Rebuild A/R and A/P Totals */
RTVASWPAR PGM(FSC880) PAID(ARAPREBLD) USER(*ALL)
EXCASWPGM PGM(FSC880) PARM(N)
/* Calculate items that will have a 5% increase in cost or 5% decrease */
/* in gross margin %, and email buyer. */
CALL PGM(IXRIQ405)
/* Send any 'READY' promos to ECU */
ECUPROMO
/* Adjust demand by items on promo. This is so that purchase */
/* suggestions for regular stocked items are not inflated by promo sales.*/
PXDEMAND
/* Use average purchase cost for warehouse MAI in SROSRO to update */
/* average purchase cost in SROSRO for RET, and average purchase cost */
/* in base item master file SROPRG. */
/* Do not share open data path, as SRBPRG may not be open for update. */
OVRDBF FILE(SRBPRG) TOFILE(SRBPRG) SHARE(*NO)
CALL PGM(AVGCST01)
/* Run miscellaneous billing - extract VEDI and COOP to be billed */
CALL PGM(CXBILL)
/* FTP Sales Orders with no invoiced lines. Normally, the FTP'ed */
/* invoice file includes cancelled order lines. This will send orders */
/* that haven't generated an invoice. */
CALL PGM(INVCUP300)
/* For miscellaneous (VEDI & COOP) billing, settle invoice to transfers */
CALL PGM(CXBILL07)
/* Cancel any held POS orders that are four days old or more */
CALL PGM(IOPMIN04)
/* Delete item notes that have expired */
CALL PGM(DMRUP101)
/* Try to reorganize Carrier Interface File */
RGZPFM FILE(ATLASPF)